Стивен Холзнер - XSLT
• > означает «больше, чем»;
• >= означает «больше или равно».
ИСПОЛЬЗОВАНИЕ СИМВОЛА <
Особенно обратите внимание на то, что непосредственно в документах XML или XSL нельзя использовать символ <, необходимо использовать ссылку на сущность <.
Для связи логических выражений логическими операциями And и Or используются ключевые слова and и or; слово not инвертирует логический смысл выражения — с истины на ложь или со лжи на истину.
В листинге 4.7 я определяю элемент <PLANET> Земли и помещаю в таблицу строки "Earth", "needs", "no" и "introduction" вместо числовых данных Земли. Я определяю, которая из планет есть Земля, при помощи предиката "[NAME='Earth']", проверяющего значение элемента <NAME>, которое, в свою очередь, представляет собой заключенный в элементе текст. Я также предоставил шаблон для других планет, удовлетворяющих предикату "[NAME!='Earth']''.
Листинг 4.7. Определение планеты Земля<?xml version="1.0"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/PLANETS">
<HTML>
<HEAD>
<TITLE>
The Planets Table
</TITLE>
</HEAD>
<BODY>
<H1>
The Planets Table
</H1>
<TABLE BORDER="2">
<TR>
<TD>Name</TD>
<TD>Mass</TD>
<TD>Radius</TD>
<TD>Day</TD>
</TR>
<xsl:apply-templates/>
</TABLE>
</BODY>
</HTML>
</xsl:template>
<xsl:template match="PLANET[NAME='Earth']">
<TR>
<TD>Earth</TD>
<TD>needs</TD>
<TD>no</TD>
<TD>introduction.</TD>
</TR>
</xsl:template>
<xsl:template match="PLANET[NAME!='Earth']">
<TR>
<TD><xsl:value-of select="NAME"/></TD>
<TD><xsl:apply-templates select="MASS"/></TD>
<TD><xsl:apply-templates select="RADIUS"/></TD>
<TD><xsl:apply-templates select="DAY"/></TD>
</TR>
</xsl:template>
<xsl:template match="MASS">
<xsl:value-of select="."/>
<xsl:text> </xsl:text>
<xsl:value-of select="@UNITS"/>
</xsl:template>
<xsl:template match="RADIUS">
<xsl:value-of select="."/>
<xsl:text> </xsl:text>
<xsl:value-of select="@UNITS"/>
</xsl:template>
<xsl:template match="DAY">
<xsl:value-of select="."/>
<xsl:text> </xsl:text>
<xsl:value-of select="@UNITS"/>
</xsl:template>
</xsl:stylesheet>
Вот результат:
<HTML>
<HEAD>
<TITLE>
The Planets Table
</TITLE>
</HEAD>
<BODY>
<Н1>
The Planets Table
</Н1>
<TABLE BORDER="2">
<TR>
<TD>Name</TD>
<TD>Mass</TD>
<TD>Radius</TD>
<TD>Day</TD>
</TR>
.
.
.
<TR>
<TD>Earth</TD>
<TD>needs</TD>
<TD>no</TD>
<TD>introduction.</TD>
</TR>
</TABLE>
</BODY>
</HTML>
Результат можно увидеть на рис. 4.1.
Рис. 4.1. Применение предикатов XPath
В следующем примере используется логическая операция >. Это правило применяется ко всем элементам <PLANET> после позиции 5:
<xsl:template match="PLANET[position() > 5]">
<xsl:value-of select="."/>
</xsl:template>
Имеется также функция true, всегда возвращающая значение true, и функция false, всегда возвращающая значение false. Функция not инвертирует логический смысл выражения, как в следующем случае, где я выбираю все элементы <PLANET>, кроме последнего:
<xsl:template match="PLANET[not(position() = last())]">
<xsl:value-of select="."/>
</xsl:template>
Наконец, функция lang возвращает истину или ложь в зависимости от того, является ли язык контекстного узла (определяемый атрибутами xml:lang) таким же, как язык, который передан в эту функцию.
Предикаты: числа
В XPath числа хранятся в формате числа с плавающей точкой двойной точности. (Технически все числа XPath хранятся в 64-разрядном формате IEEE числа с плавающей точкой двойной точности, floating-point double.) Все числа хранятся как числа с двойной точностью — даже целые числа, как 5 в рассматриваемом примере:
<xsl:template match="PLANET[position() > 5]">
<xsl:value-of select="."/>
</xsl:template>
Над числами можно производить ряд операций:
• + сложение;
• - вычитание;
• * умножение;
• div деление (символ /, соответствующий делению в других языках, в XML, XSL и XPath уже занят);
• mod возвращает значение деления по модулю двух чисел (остаток после деления первого числа на второе).
Например, элемент <xsl:value-of select="180+420"/> вставит в выходной документ строку "600". В следующем примере выбираются все планеты, у которых отношение дня (измеренного в днях Земли) к массе (где масса Земли принята за 1) больше 100:
<xsl:template match="PLANETS">
<HTML>
<BODY>
<xsl:apply-templates select="PLANET[DAY div MASS > 100]"/>
</BODY>
</HTML>
</xsl:template>
XPath также поддерживает следующие функции работы с числами:
• ceiling(). Возвращает наименьшее целое, большее, чем переданное функции число;
• floor(). Возвращает наибольшее целое, меньшее, чем переданное функции число;
• round(). Округляет переданное число до ближайшего целого;
• sum(). Возвращает сумму переданных функции чисел.
Например, среднюю массу планет в planets.xml можно найти так, как в листинге 4.8:
Листинг 4.8. Вычисление средней массы планет<?xml version="1.0"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml"/>
<xsl:template match="PLANETS">
<HTML>
<BODY>
The average planetary mass is:
<xsl:value-of select="sum(child::PLANET/child::MASS) div count(child::PLANET)"/>
</BODY>
</HTML>
</xsl:template>
</xsl:stylesheet>
Строки
В XPath строки формируются из символов Unicode, как можно было предположить. Ряд функций специально предназначен для работы со строками:
• string(object object1). Преобразует объект в строку;
• starts-with(string string1, string string2). Возвращает истину, если первая строка начинается (starts with) со второй строки;
• contains(string string1, string string2). Возвращает истину, если первая строка содержит (contains) вторую строку;
• substring(string string1, number offset number length). Возвращает length символов из строки, начиная со смещения offset;
• substring-before(string string1, string string2). Возвращает часть строки string1 до первого вхождения строки string2;
• substring-after(string string1, string string2). Возвращает часть строки string1 после первого вхождения string2;
• string-length(string string1). Возвращает количество символов в строке string1;
• normalize-space(string string1). Возвращает строку string1 после отбрасывания лидирующих и завершающих символов-разделителей и замены нескольких последовательных разделителей на один пробел;
• translate(string string1, string string2, string string3). Возвращает строку string1, в которой все вхождения символов в строке string2 заменены на соответствующие символы в строке string3;
• concat(string string1, string string2, ...). Возвращает конкатенацию (объединение) всех строк.
Есть еще одна строковая функция, о которой вам следует знать, входящая не в XPath, а в XSLT:
• format-number(number number1, string string2, string string3). Возвращает строку, содержащую число number1 в виде форматированной строки, используя string2 в качестве форматирующей строки (форматирующие строки создаются так же, как для метода Java java.text.DecimalFormat) и string3 как возможную строку локализации.
