Алексей Валиков - Технология XSLT
Структурно результирующий фрагмент дерева тоже является деревом — это просто отрезанная ветка. Шаблоны генерируют ветки, используя собственные инструкции, а также результаты выполнения шаблонов, которые они вызывают и в итоге множество веток срастается в одно большое дерево, которое и является целью преобразования.
Между тем, результирующие фрагменты деревьев могут и не попасть в само результирующее дерево, то есть совершенно не факт, что они всегда будут его частями. Например, результирующий фрагмент дерева может быть присвоен переменной как начальное значение. Это предоставляет следующие, очень интересные возможности.
□ Переменная может содержать дерево, являющееся результатом обработки документа. К сожалению, в чистом XSLT нельзя повторно обрабатывать части документов, однако, это реализуется при помощи механизма расширений.
□ Дерево может быть определено один раз в виде значения переменной и использовано несколько раз в выходящем документе.
Пример Листинг 3.10. Входящий документ<href>
<location>http://www.xsltdev.ru</location>
</href>
Листинг 3.11. Преобразование<xsl:stylesheet
version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:variable name="href">
<body>
<xsl:apply-templates select="href"/>
</body>
</xsl:variable>
<xsl:template match="href">
<B>You may visit the <A HREF="{location}">following link</A>.</B>
</xsl:template>
<xsl:template match="/">
<result>
<xsl:text>
Result as string:
</xsl:text>
<xsl:value-of select="$href"/>
<xsl:text>
Result as tree:
</xsl:text>
<xsl:copy-of select="$href"/>
<xsl:text>
</xsl:text>
</result>
</xsl:template>
</xsl:stylesheet>
Листинг 3.12. Выходящий документ<result>
Result as string:
You may visit the following link.
Result as tree:
<body><B>You may visit the <A HREF="http://www.xsltdev.ru">following
link</A>.</B>
</body>
</result>
Это преобразование легко понять, если обратиться к рис. 3.18.
Рис. 3.18. Генерация выходящего дерева с использованием переменных
Переменной href присваивается дерево, содержащее результат обработки элемента href, находящегося в корне входящего документа. Затем переменная href дважды используется в результирующем документе: один раз как строка, принадлежащая текстовому узлу, и один раз как результирующий фрагмент дерева.
Дерево может быть преобразовано в булевое значение, число или строку. Некоторые процессоры позволяют также преобразовывать дерево во множество узлов, которое содержит единственный элемент — корневой узел этого дерева. Такие возможности бывают весьма полезными, но не являются, к сожалению, стандартными в текущей версии языка.
При преобразовании результирующего фрагмента дерева в булевое значение результатом всегда будет true, поскольку дерево никогда не бывает "пустым" — в нем всегда присутствует корневой узел.
При преобразовании дерева в строку результатом является конкатенация (строковое сложение) всех текстовых узлов дерева в порядке просмотра.
ПримерРезультирующий фрагмент дерева
<body>
<B>You may visit the <A HREF="http://www.xsltdev.ru">following
link</A>.</B>
</body>
приводится к строке
The result is: You may visit the following link.
При приведении дерева к числу, оно сначала преобразовывается в строку, а затем в число. Это означает, что деревья, в принципе, можно использовать в арифметических операциях, несмотря на то, что они для этого не предназначены.
Пример Листинг 3.13. Входящий документ:<numbers>
<integer>1</integer>
<real>1</real>
<integer>2</integer>
<real>2</real>
<integer>3</integer>
<real>3.5</real>
</numbers>
Листинг 3.14. Преобразование:<xsl:stylesheet
version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:variable name="integers">
<integers><xsl:copy-of select="/numbers/integer"/></integers>
</xsl:variable>
<xsl:variable name="reals">
<reals><xsl:copy-of select="/numbers/real"/></reals>
</xsl:variable>
<xsl:template match="/">
<result>
<xsl:text>
 Integers:
</xsl:text>
<xsl:value-of select="$integers"/>
<xsl:text>
Reals:
</xsl:text>
<xsl:value-of select="$reals"/>
<xsl:text>
Reals minus integers:
</xsl:text>
<xsl:value-of select="$reals - $integers"/>
<xsl:text>
</xsl:text>
</result>
</xsl:template>
</xsl:stylesheet>
Листинг 3.15. Результат<result>
Integers:
123
Reals:
123.5
Reals minus integers:
0.5
</result>
Таблица преобразования типов
Для удобства использования все взаимные преобразования типов сведены в одну таблицу (табл. 3.2).
Таблица 3.2. Взаимные преобразования типов данных XSLT
Преобразовываемый тип Целевой тип boolean (булевое значение) number (число) string (строка) node-set (множество узлов) tree (дерево) boolean (булевое значение) 0 → false NaN → false другое → true пустая → false непустая → true пустое → false другое → true всегда true number (число) false → 0 true → 1 разбирается, как число в десятичном формате мн-во → строка → число дерево → строка → число string (строка) false → "false" true → "true" десятичная запись числа строковое значение первого узла в порядке просмотра строковое сложение всех текстовых узлов дерева node-set (множество узлов) нет нет нет нет tree (дерево) нет нет нет нетПеременные
Несмотря на отсутствие побочных эффектов, которое является одним из основных принципов XSLT, в преобразованиях можно использовать переменные. Переменная определяется как имя, с которым связывается некоторое значение, например:
<xsl:variable name="url" select="'http://www.xsltdev.ru'"/>
создаст переменную с именем url и присвоит ей строковое значение "http://www.xsltdev.ru". После этого переменную можно использовать в выражениях, например:
<xsl:value-of select="concat('Welcome to ', $url)"/>
Для того чтобы отличать переменные от путей выборки, в выражениях их именам предшествует префикс "$": к значению переменной с именем url мы обращались как к $url.
Каждая из переменных имеет собственную область видимости (англ. visibility scope) — область документа преобразования, в которой может быть использовано ее значение. В зависимости от этого переменные могут быть глобальными (видимыми во всем преобразовании) и локальными (видимыми только в своем родительском элементе).
Помимо переменных, в преобразованиях и шаблонных правилах могут также определяться параметры. Принцип их действия полностью совпадает с принципом действия переменных с той лишь разницей, что значения, присваиваемые параметрам, являются значениями по умолчанию и могут быть изменены извне — например, вызывающим шаблонное правило элементом типа xsl:apply-templates или xsl:call-template, или самим процессором, если речь идет о глобальных параметрах.
Использование переменных и параметров в XSLT отличается от их использования в привычных процедурных языках программирования типа С++, Java или Object Pascal из-за того, что их значения не могут изменяться. После того, как переменной или параметру присвоено некоторое изначальное значение, оно будет оставаться неизменным.
