W Cat - Описание языка PascalABC.NET
Библиотеки dll (dynamically linked libraries):
* содержат группу взаимосвязанных подпрограмм
* находятся в откомпилированном файле
* предназначены для обращения к ним из различных программ
Они находятся в файле с расширением .dll либо в текущем каталоге приложения (локальные), либо в системном каталоге (глобальные библиотеки). Глобальными библиотеками могут пользоваться одновременно несколько приложений.
По своему назначению библиотеки очень похожи на модули, однако, имеют ряд важных отличий.
Отличия библиотек от модулей* При создании из модулей исполняемого файла .exe программа-линковщик помещает в него только те подпрограммы, переменные, типы и константы, которые используются (вызываются) в основной программе. При компиляции же библиотеки в нее добавляются все подпрограммы, потому что неизвестно, какие подпрограммы потребуются конкретному приложению.
* Библиотеки .dll при выполнении программы полностью загружаются в оперативную память.
* Библиотеки .dll часто используются одновременно несколькими программами.
* Библиотека .dll может быть написана и откомпилирована на одном языке, а обращаться к ней можно из программ, написанных на других языках. Например, программа на PascalABC.NET может вызывать функцию из библиотеки, созданной на языке C# и наобороот. Таким образом, библиотеки обеспечивают межъязыковое взаимодействие.
Структура библиотеки
Библиотека имеет практически ту же структуру, что и модуль:
library имя библиотеки;
interface
раздел интерфейса
implementation
раздел реализации
end.
Имя библиотеки должно совпадать с именем pas-файла, в котором библиотека находится.
Имеется также упрощенный синтаксис библиотек - без разделов интерфейса и реализации, совпадающий с упрощенным синтаксисом модулей (за исключением заголовка).
В результате компиляции библиотеки в текущем каталоге создаётся .dll-файл, содержащий откомпилированную библиотеку.
Подключение библиотеки к основной программеДля подключения библиотеки к основной программе используется директива компилятора {$reference ИмяБиблиотеки}. Например:
{$reference ABC.dll}
{$reference ABC1.dll}
begin
writeln(a.GetType);
end.
Подключение библиотеки может проводиться в любом месте исходного файла.
Библиотеки ABC и ABC1 имеют соответственно вид:
library ABC;
var a: integer;
end.
и
library ABC1;
var a: real;
end.
Алгоритм поиска имен в библиотекахВ первую очередь имя ищется в исходном модуле, затем в модулях, подключенных в разделе uses в порядке справа налево, и только потом - в подключенных библиотеках в порядке подключения.
Согласно этому правилу в примере из предыдущего пункта переменная a будет иметь тип integer.
В случае коллизии имен используемое имя можно предварять именем библиотеки с последующей точкой:
{$reference ABC.dll}
{$reference ABC1.dll}
begin
writeln(ABC1.a.GetType);
end.
Документирующие комментарии
Можно помечать заголовки процедур, функций, методов, имена классов, типов, констант и переменных так называемыми документирующими комментариями. Документирующие комментарии всплывают в подсказках редактора при наведении курсора мыши на слово, при открытии скобки после имени подпрограммы и при выборе поля из списка полей, выпадающих при нажатии точки после имени. Система всплывающих подсказок в редакторе получила название Intellisense.
Документирующий комментарий располагается на строчке, предшествующей помечаемому объекту, и начинается с символов ///. Например:
const
/// Константа Pi
Pi = 3.14;
type
/// TTT - синоним целого типа
TTT = integer;
/// Документирующий комментарий класса XXX
XXX = class
end;
/// Документирующий комментарий процедуры p
procedure p(a : integer);
begin
end;
var
/// Документирующий комментарий переменной t1
t1: TTT;
Документирующие комментарии могут занимать несколько строк, каждая из которых должна начинаться с /// . Для комментирования подпрограмм можно использовать в первой строке документирующий комментарий ///-, тогда его содержимое меняет заголовок подпрограммы в подсказке при наведении курсора мыши. Например:
///- Exclude(var s : set of T; el : T)
///Удаляет элемент el из множества s
procedure Exclude(var s: TypedSet; el: object);
Если первая строка документирующего комментария имеет вид ///--, то подсказка не всплывает. Это делается для элементов, которые хочется скрыть от системы всплывающих подсказок.
Классы
Обзор классов и объектов
Класс представляет собой составной тип, состоящий из полей (переменных), методов (процедур и функций) и свойств. Описание класса имеет вид:
type
имя класса = class
секция1
секция2
...
end;
Каждая секция имеет вид:
модификатор доступа
описания полей
объявления или описания методов и описания свойств
Модификатор доступа в первой секции может отсутствовать, при этом подразумевается модификатор internal (видимость всюду внутри сборки).
Методы могут описываться как внутри, так и вне класса. При описании метода внутри класса его имя предваряется именем класса с последующей точкой. Например:
type
Person = class
private
fName: string;
fAge: integer;
public
constructor Create(Name: string; Age: integer);
begin
fName := Name;
fAge := Age;
end;
procedure Print;
property Name: string read fName;
property Age: integer read fAge;
end;
procedure Person.Print;
begin
writelnFormat('Имя: {0} Возраст: {1}', Name, Age);
end;
После слова class в скобках может быть указано имя класса-предка (см. Наследование), а также через запятую список поддерживаемых интерфейсов.
Перед словом class может быть указано ключевое слово final в этом случае от класса запрещено наследовать.
Все описания и объявления внутри класса образуют тело класса. Поля и методы образуют интерфейс класса. Инициализаторы полей описаны здесь.
Классы могут описываться только на глобальном уровне. Локальные определения классов (т.е. определения в разделе описания подпрограмм) запрещены.
Переменные типа классВ языке PascalABC.NET классы являются ссылочными типами. Это значит, что переменная типа класс хранит в действительности ссылку на объект.
Переменные типа класс называются объектами или экземплярами класса. Они инициализируются вызовом конструктора класса - специального метода, выделяющего память под объект класса и инициализирующего его поля:
var p: Person := new Person('Иванов',20);
После инициализации через переменную типа класс можно обращаться к публичным членам класса (полям, методам, свойствам), используя точечную нотацию:
Print(p.Name,p.Age);
p.Print;
Вывод переменной типа классПо умолчанию процедура write для переменной типа класс выводит содержимое её публичных полей и свойств в круглых скобках через запятую:
write(p); // Иванов 20
Чтобы изменить это поведение, в классе следует переопределить виртуальный метод ToString класса Object - в этом случае именно он будет вызываться при выводе объекта.
Например:
type
Person = class
...
function ToString: string; override;
begin
Result := string.Format('Имя: {0} Возраст: {1}', Name, Age);
end;
end;
...
var p: Person := new Person('Иванов',20);
writeln(p); // Имя: Иванов Возраст: 20
Присваивание и передача в качестве параметров подпрограммПеременная типа класс является ссылкой и хранит ссылку на объект, создаваемый вызовом конструктора.
Как ссылка переменная типа класс может хранить значение nil:
p := nil;
...
if p = nil then ...
При присваивании переменных типа класс копируется только ссылка. После присваивания обе переменные типа класс будут ссылаться на один объект и совместно модифицировать его:
var p1,p2: Person;
...
p1 := new Person('Петров',20);
p2 := p1;
p1.IncAge;
p2.Print; // Имя: Петров Возраст: 21
Сравнение на равенствоПри сравнении переменных типа класс на равенство сравниваются ссылки, а не значения.
var p1 := new Person('Петров',20);
var p2 := new Person('Петров',20);
writeln(p1=p2); // False
p2 := p1;
writeln(p1=p2); // True
Это поведение можно изменить, перегрузив операцию = для класса.
Видимость членов класса и модификаторы доступа
Каждое поле, метод или свойство класса имеет модификатор (атрибут) доступа, задающий правила его видимости. В PascalABC.NET существуют четыре вида модификаторов доступа: public (открытый), private (закрытый), protected (защищенный) и internal (внутренний). К члену класса, имеющему атрибут public, можно обратиться из любого места программы, члены класса с атрибутом private доступны только внутри методов этого класса, члены класса с атрибутом protected доступны внутри методов этого класса и всех его подклассов, члены класса с атрибутом internal доступны внутри сборки (термин .NET, сборка в нашем понимании - это множество файлов, необходимых для генерации .exe или .dll-файла). Кроме того, private и protected члены видны отовсюду в пределах модуля, в котором определен класс.
